mirror of
https://git.planet-casio.com/Lephenixnoir/OpenLibm.git
synced 2025-01-01 06:23:39 +01:00
185 lines
6.2 KiB
Fortran
185 lines
6.2 KiB
Fortran
*DECK HTRIDI
|
|
SUBROUTINE HTRIDI (NM, N, AR, AI, D, E, E2, TAU)
|
|
C***BEGIN PROLOGUE HTRIDI
|
|
C***PURPOSE Reduce a complex Hermitian matrix to a real symmetric
|
|
C tridiagonal matrix using unitary similarity
|
|
C transformations.
|
|
C***LIBRARY SLATEC (EISPACK)
|
|
C***CATEGORY D4C1B1
|
|
C***TYPE SINGLE PRECISION (HTRIDI-S)
|
|
C***KEYWORDS EIGENVALUES, EIGENVECTORS, EISPACK
|
|
C***AUTHOR Smith, B. T., et al.
|
|
C***DESCRIPTION
|
|
C
|
|
C This subroutine is a translation of a complex analogue of
|
|
C the ALGOL procedure TRED1, NUM. MATH. 11, 181-195(1968)
|
|
C by Martin, Reinsch, and Wilkinson.
|
|
C HANDBOOK FOR AUTO. COMP., VOL.II-LINEAR ALGEBRA, 212-226(1971).
|
|
C
|
|
C This subroutine reduces a COMPLEX HERMITIAN matrix
|
|
C to a real symmetric tridiagonal matrix using
|
|
C unitary similarity transformations.
|
|
C
|
|
C On INPUT
|
|
C
|
|
C NM must be set to the row dimension of the two-dimensional
|
|
C array parameters, AR and AI, as declared in the calling
|
|
C program dimension statement. NM is an INTEGER variable.
|
|
C
|
|
C N is the order of the matrix A=(AR,AI). N is an INTEGER
|
|
C variable. N must be less than or equal to NM.
|
|
C
|
|
C AR and AI contain the real and imaginary parts, respectively,
|
|
C of the complex Hermitian input matrix. Only the lower
|
|
C triangle of the matrix need be supplied. AR and AI are two-
|
|
C dimensional REAL arrays, dimensioned AR(NM,N) and AI(NM,N).
|
|
C
|
|
C On OUTPUT
|
|
C
|
|
C AR and AI contain some information about the unitary trans-
|
|
C formations used in the reduction in the strict lower triangle
|
|
C of AR and the full lower triangle of AI. The rest of the
|
|
C matrices are unaltered.
|
|
C
|
|
C D contains the diagonal elements of the real symmetric
|
|
C tridiagonal matrix. D is a one-dimensional REAL array,
|
|
C dimensioned D(N).
|
|
C
|
|
C E contains the subdiagonal elements of the real tridiagonal
|
|
C matrix in its last N-1 positions. E(1) is set to zero.
|
|
C E is a one-dimensional REAL array, dimensioned E(N).
|
|
C
|
|
C E2 contains the squares of the corresponding elements of E.
|
|
C E2(1) is set to zero. E2 may coincide with E if the squares
|
|
C are not needed. E2 is a one-dimensional REAL array,
|
|
C dimensioned E2(N).
|
|
C
|
|
C TAU contains further information about the transformations.
|
|
C TAU is a one-dimensional REAL array, dimensioned TAU(2,N).
|
|
C
|
|
C Calls PYTHAG(A,B) for sqrt(A**2 + B**2).
|
|
C
|
|
C Questions and comments should be directed to B. S. Garbow,
|
|
C APPLIED MATHEMATICS DIVISION, ARGONNE NATIONAL LABORATORY
|
|
C ------------------------------------------------------------------
|
|
C
|
|
C***REFERENCES B. T. Smith, J. M. Boyle, J. J. Dongarra, B. S. Garbow,
|
|
C Y. Ikebe, V. C. Klema and C. B. Moler, Matrix Eigen-
|
|
C system Routines - EISPACK Guide, Springer-Verlag,
|
|
C 1976.
|
|
C***ROUTINES CALLED PYTHAG
|
|
C***REVISION HISTORY (YYMMDD)
|
|
C 760101 DATE WRITTEN
|
|
C 890831 Modified array declarations. (WRB)
|
|
C 890831 REVISION DATE from Version 3.2
|
|
C 891214 Prologue converted to Version 4.0 format. (BAB)
|
|
C 920501 Reformatted the REFERENCES section. (WRB)
|
|
C***END PROLOGUE HTRIDI
|
|
C
|
|
INTEGER I,J,K,L,N,II,NM,JP1
|
|
REAL AR(NM,*),AI(NM,*),D(*),E(*),E2(*),TAU(2,*)
|
|
REAL F,G,H,FI,GI,HH,SI,SCALE
|
|
REAL PYTHAG
|
|
C
|
|
C***FIRST EXECUTABLE STATEMENT HTRIDI
|
|
TAU(1,N) = 1.0E0
|
|
TAU(2,N) = 0.0E0
|
|
C
|
|
DO 100 I = 1, N
|
|
100 D(I) = AR(I,I)
|
|
C .......... FOR I=N STEP -1 UNTIL 1 DO -- ..........
|
|
DO 300 II = 1, N
|
|
I = N + 1 - II
|
|
L = I - 1
|
|
H = 0.0E0
|
|
SCALE = 0.0E0
|
|
IF (L .LT. 1) GO TO 130
|
|
C .......... SCALE ROW (ALGOL TOL THEN NOT NEEDED) ..........
|
|
DO 120 K = 1, L
|
|
120 SCALE = SCALE + ABS(AR(I,K)) + ABS(AI(I,K))
|
|
C
|
|
IF (SCALE .NE. 0.0E0) GO TO 140
|
|
TAU(1,L) = 1.0E0
|
|
TAU(2,L) = 0.0E0
|
|
130 E(I) = 0.0E0
|
|
E2(I) = 0.0E0
|
|
GO TO 290
|
|
C
|
|
140 DO 150 K = 1, L
|
|
AR(I,K) = AR(I,K) / SCALE
|
|
AI(I,K) = AI(I,K) / SCALE
|
|
H = H + AR(I,K) * AR(I,K) + AI(I,K) * AI(I,K)
|
|
150 CONTINUE
|
|
C
|
|
E2(I) = SCALE * SCALE * H
|
|
G = SQRT(H)
|
|
E(I) = SCALE * G
|
|
F = PYTHAG(AR(I,L),AI(I,L))
|
|
C .......... FORM NEXT DIAGONAL ELEMENT OF MATRIX T ..........
|
|
IF (F .EQ. 0.0E0) GO TO 160
|
|
TAU(1,L) = (AI(I,L) * TAU(2,I) - AR(I,L) * TAU(1,I)) / F
|
|
SI = (AR(I,L) * TAU(2,I) + AI(I,L) * TAU(1,I)) / F
|
|
H = H + F * G
|
|
G = 1.0E0 + G / F
|
|
AR(I,L) = G * AR(I,L)
|
|
AI(I,L) = G * AI(I,L)
|
|
IF (L .EQ. 1) GO TO 270
|
|
GO TO 170
|
|
160 TAU(1,L) = -TAU(1,I)
|
|
SI = TAU(2,I)
|
|
AR(I,L) = G
|
|
170 F = 0.0E0
|
|
C
|
|
DO 240 J = 1, L
|
|
G = 0.0E0
|
|
GI = 0.0E0
|
|
C .......... FORM ELEMENT OF A*U ..........
|
|
DO 180 K = 1, J
|
|
G = G + AR(J,K) * AR(I,K) + AI(J,K) * AI(I,K)
|
|
GI = GI - AR(J,K) * AI(I,K) + AI(J,K) * AR(I,K)
|
|
180 CONTINUE
|
|
C
|
|
JP1 = J + 1
|
|
IF (L .LT. JP1) GO TO 220
|
|
C
|
|
DO 200 K = JP1, L
|
|
G = G + AR(K,J) * AR(I,K) - AI(K,J) * AI(I,K)
|
|
GI = GI - AR(K,J) * AI(I,K) - AI(K,J) * AR(I,K)
|
|
200 CONTINUE
|
|
C .......... FORM ELEMENT OF P ..........
|
|
220 E(J) = G / H
|
|
TAU(2,J) = GI / H
|
|
F = F + E(J) * AR(I,J) - TAU(2,J) * AI(I,J)
|
|
240 CONTINUE
|
|
C
|
|
HH = F / (H + H)
|
|
C .......... FORM REDUCED A ..........
|
|
DO 260 J = 1, L
|
|
F = AR(I,J)
|
|
G = E(J) - HH * F
|
|
E(J) = G
|
|
FI = -AI(I,J)
|
|
GI = TAU(2,J) - HH * FI
|
|
TAU(2,J) = -GI
|
|
C
|
|
DO 260 K = 1, J
|
|
AR(J,K) = AR(J,K) - F * E(K) - G * AR(I,K)
|
|
1 + FI * TAU(2,K) + GI * AI(I,K)
|
|
AI(J,K) = AI(J,K) - F * TAU(2,K) - G * AI(I,K)
|
|
1 - FI * E(K) - GI * AR(I,K)
|
|
260 CONTINUE
|
|
C
|
|
270 DO 280 K = 1, L
|
|
AR(I,K) = SCALE * AR(I,K)
|
|
AI(I,K) = SCALE * AI(I,K)
|
|
280 CONTINUE
|
|
C
|
|
TAU(2,L) = -SI
|
|
290 HH = D(I)
|
|
D(I) = AR(I,I)
|
|
AR(I,I) = HH
|
|
AI(I,I) = SCALE * SQRT(H)
|
|
300 CONTINUE
|
|
C
|
|
RETURN
|
|
END
|