mirror of
https://git.planet-casio.com/Lephenixnoir/OpenLibm.git
synced 2025-01-01 06:23:39 +01:00
82 lines
2.5 KiB
Fortran
82 lines
2.5 KiB
Fortran
*DECK IDAMAX
|
|
INTEGER FUNCTION IDAMAX (N, DX, INCX)
|
|
C***BEGIN PROLOGUE IDAMAX
|
|
C***PURPOSE Find the smallest index of that component of a vector
|
|
C having the maximum magnitude.
|
|
C***LIBRARY SLATEC (BLAS)
|
|
C***CATEGORY D1A2
|
|
C***TYPE DOUBLE PRECISION (ISAMAX-S, IDAMAX-D, ICAMAX-C)
|
|
C***KEYWORDS BLAS, LINEAR ALGEBRA, MAXIMUM COMPONENT, VECTOR
|
|
C***AUTHOR Lawson, C. L., (JPL)
|
|
C Hanson, R. J., (SNLA)
|
|
C Kincaid, D. R., (U. of Texas)
|
|
C Krogh, F. T., (JPL)
|
|
C***DESCRIPTION
|
|
C
|
|
C B L A S Subprogram
|
|
C Description of Parameters
|
|
C
|
|
C --Input--
|
|
C N number of elements in input vector(s)
|
|
C DX double precision vector with N elements
|
|
C INCX storage spacing between elements of DX
|
|
C
|
|
C --Output--
|
|
C IDAMAX smallest index (zero if N .LE. 0)
|
|
C
|
|
C Find smallest index of maximum magnitude of double precision DX.
|
|
C IDAMAX = first I, I = 1 to N, to maximize ABS(DX(IX+(I-1)*INCX)),
|
|
C where IX = 1 if INCX .GE. 0, else IX = 1+(1-N)*INCX.
|
|
C
|
|
C***REFERENCES C. L. Lawson, R. J. Hanson, D. R. Kincaid and F. T.
|
|
C Krogh, Basic linear algebra subprograms for Fortran
|
|
C usage, Algorithm No. 539, Transactions on Mathematical
|
|
C Software 5, 3 (September 1979), pp. 308-323.
|
|
C***ROUTINES CALLED (NONE)
|
|
C***REVISION HISTORY (YYMMDD)
|
|
C 791001 DATE WRITTEN
|
|
C 890531 Changed all specific intrinsics to generic. (WRB)
|
|
C 890531 REVISION DATE from Version 3.2
|
|
C 891214 Prologue converted to Version 4.0 format. (BAB)
|
|
C 900821 Modified to correct problem with a negative increment.
|
|
C (WRB)
|
|
C 920501 Reformatted the REFERENCES section. (WRB)
|
|
C***END PROLOGUE IDAMAX
|
|
DOUBLE PRECISION DX(*), DMAX, XMAG
|
|
INTEGER I, INCX, IX, N
|
|
C***FIRST EXECUTABLE STATEMENT IDAMAX
|
|
IDAMAX = 0
|
|
IF (N .LE. 0) RETURN
|
|
IDAMAX = 1
|
|
IF (N .EQ. 1) RETURN
|
|
C
|
|
IF (INCX .EQ. 1) GOTO 20
|
|
C
|
|
C Code for increments not equal to 1.
|
|
C
|
|
IX = 1
|
|
IF (INCX .LT. 0) IX = (-N+1)*INCX + 1
|
|
DMAX = ABS(DX(IX))
|
|
IX = IX + INCX
|
|
DO 10 I = 2,N
|
|
XMAG = ABS(DX(IX))
|
|
IF (XMAG .GT. DMAX) THEN
|
|
IDAMAX = I
|
|
DMAX = XMAG
|
|
ENDIF
|
|
IX = IX + INCX
|
|
10 CONTINUE
|
|
RETURN
|
|
C
|
|
C Code for increments equal to 1.
|
|
C
|
|
20 DMAX = ABS(DX(1))
|
|
DO 30 I = 2,N
|
|
XMAG = ABS(DX(I))
|
|
IF (XMAG .GT. DMAX) THEN
|
|
IDAMAX = I
|
|
DMAX = XMAG
|
|
ENDIF
|
|
30 CONTINUE
|
|
RETURN
|
|
END
|