mirror of
https://git.planet-casio.com/Lephenixnoir/OpenLibm.git
synced 2025-01-01 06:23:39 +01:00
190 lines
6.1 KiB
Fortran
190 lines
6.1 KiB
Fortran
*DECK IMTQL2
|
|
SUBROUTINE IMTQL2 (NM, N, D, E, Z, IERR)
|
|
C***BEGIN PROLOGUE IMTQL2
|
|
C***PURPOSE Compute the eigenvalues and eigenvectors of a symmetric
|
|
C tridiagonal matrix using the implicit QL method.
|
|
C***LIBRARY SLATEC (EISPACK)
|
|
C***CATEGORY D4A5, D4C2A
|
|
C***TYPE SINGLE PRECISION (IMTQL2-S)
|
|
C***KEYWORDS EIGENVALUES, EIGENVECTORS, EISPACK
|
|
C***AUTHOR Smith, B. T., et al.
|
|
C***DESCRIPTION
|
|
C
|
|
C This subroutine is a translation of the ALGOL procedure IMTQL2,
|
|
C NUM. MATH. 12, 377-383(1968) by Martin and Wilkinson,
|
|
C as modified in NUM. MATH. 15, 450(1970) by Dubrulle.
|
|
C HANDBOOK FOR AUTO. COMP., VOL.II-LINEAR ALGEBRA, 241-248(1971).
|
|
C
|
|
C This subroutine finds the eigenvalues and eigenvectors
|
|
C of a SYMMETRIC TRIDIAGONAL matrix by the implicit QL method.
|
|
C The eigenvectors of a FULL SYMMETRIC matrix can also
|
|
C be found if TRED2 has been used to reduce this
|
|
C full matrix to tridiagonal form.
|
|
C
|
|
C On INPUT
|
|
C
|
|
C NM must be set to the row dimension of the two-dimensional
|
|
C array parameter, Z, as declared in the calling program
|
|
C dimension statement. NM is an INTEGER variable.
|
|
C
|
|
C N is the order of the matrix. N is an INTEGER variable.
|
|
C N must be less than or equal to NM.
|
|
C
|
|
C D contains the diagonal elements of the symmetric tridiagonal
|
|
C matrix. D is a one-dimensional REAL array, dimensioned D(N).
|
|
C
|
|
C E contains the subdiagonal elements of the symmetric
|
|
C tridiagonal matrix in its last N-1 positions. E(1) is
|
|
C arbitrary. E is a one-dimensional REAL array, dimensioned
|
|
C E(N).
|
|
C
|
|
C Z contains the transformation matrix produced in the reduction
|
|
C by TRED2, if performed. This transformation matrix is
|
|
C necessary if you want to obtain the eigenvectors of the full
|
|
C symmetric matrix. If the eigenvectors of the symmetric
|
|
C tridiagonal matrix are desired, Z must contain the identity
|
|
C matrix. Z is a two-dimensional REAL array, dimensioned
|
|
C Z(NM,N).
|
|
C
|
|
C On OUTPUT
|
|
C
|
|
C D contains the eigenvalues in ascending order. If an
|
|
C error exit is made, the eigenvalues are correct but
|
|
C unordered for indices 1, 2, ..., IERR-1.
|
|
C
|
|
C E has been destroyed.
|
|
C
|
|
C Z contains orthonormal eigenvectors of the full symmetric
|
|
C or symmetric tridiagonal matrix, depending on what it
|
|
C contained on input. If an error exit is made, Z contains
|
|
C the eigenvectors associated with the stored eigenvalues.
|
|
C
|
|
C IERR is an INTEGER flag set to
|
|
C Zero for normal return,
|
|
C J if the J-th eigenvalue has not been
|
|
C determined after 30 iterations.
|
|
C The eigenvalues and eigenvectors should be correct
|
|
C for indices 1, 2, ..., IERR-1, but the eigenvalues
|
|
C are not ordered.
|
|
C
|
|
C Calls PYTHAG(A,B) for sqrt(A**2 + B**2).
|
|
C
|
|
C Questions and comments should be directed to B. S. Garbow,
|
|
C APPLIED MATHEMATICS DIVISION, ARGONNE NATIONAL LABORATORY
|
|
C ------------------------------------------------------------------
|
|
C
|
|
C***REFERENCES B. T. Smith, J. M. Boyle, J. J. Dongarra, B. S. Garbow,
|
|
C Y. Ikebe, V. C. Klema and C. B. Moler, Matrix Eigen-
|
|
C system Routines - EISPACK Guide, Springer-Verlag,
|
|
C 1976.
|
|
C***ROUTINES CALLED PYTHAG
|
|
C***REVISION HISTORY (YYMMDD)
|
|
C 760101 DATE WRITTEN
|
|
C 890831 Modified array declarations. (WRB)
|
|
C 890831 REVISION DATE from Version 3.2
|
|
C 891214 Prologue converted to Version 4.0 format. (BAB)
|
|
C 920501 Reformatted the REFERENCES section. (WRB)
|
|
C***END PROLOGUE IMTQL2
|
|
C
|
|
INTEGER I,J,K,L,M,N,II,NM,MML,IERR
|
|
REAL D(*),E(*),Z(NM,*)
|
|
REAL B,C,F,G,P,R,S,S1,S2
|
|
REAL PYTHAG
|
|
C
|
|
C***FIRST EXECUTABLE STATEMENT IMTQL2
|
|
IERR = 0
|
|
IF (N .EQ. 1) GO TO 1001
|
|
C
|
|
DO 100 I = 2, N
|
|
100 E(I-1) = E(I)
|
|
C
|
|
E(N) = 0.0E0
|
|
C
|
|
DO 240 L = 1, N
|
|
J = 0
|
|
C .......... LOOK FOR SMALL SUB-DIAGONAL ELEMENT ..........
|
|
105 DO 110 M = L, N
|
|
IF (M .EQ. N) GO TO 120
|
|
S1 = ABS(D(M)) + ABS(D(M+1))
|
|
S2 = S1 + ABS(E(M))
|
|
IF (S2 .EQ. S1) GO TO 120
|
|
110 CONTINUE
|
|
C
|
|
120 P = D(L)
|
|
IF (M .EQ. L) GO TO 240
|
|
IF (J .EQ. 30) GO TO 1000
|
|
J = J + 1
|
|
C .......... FORM SHIFT ..........
|
|
G = (D(L+1) - P) / (2.0E0 * E(L))
|
|
R = PYTHAG(G,1.0E0)
|
|
G = D(M) - P + E(L) / (G + SIGN(R,G))
|
|
S = 1.0E0
|
|
C = 1.0E0
|
|
P = 0.0E0
|
|
MML = M - L
|
|
C .......... FOR I=M-1 STEP -1 UNTIL L DO -- ..........
|
|
DO 200 II = 1, MML
|
|
I = M - II
|
|
F = S * E(I)
|
|
B = C * E(I)
|
|
IF (ABS(F) .LT. ABS(G)) GO TO 150
|
|
C = G / F
|
|
R = SQRT(C*C+1.0E0)
|
|
E(I+1) = F * R
|
|
S = 1.0E0 / R
|
|
C = C * S
|
|
GO TO 160
|
|
150 S = F / G
|
|
R = SQRT(S*S+1.0E0)
|
|
E(I+1) = G * R
|
|
C = 1.0E0 / R
|
|
S = S * C
|
|
160 G = D(I+1) - P
|
|
R = (D(I) - G) * S + 2.0E0 * C * B
|
|
P = S * R
|
|
D(I+1) = G + P
|
|
G = C * R - B
|
|
C .......... FORM VECTOR ..........
|
|
DO 180 K = 1, N
|
|
F = Z(K,I+1)
|
|
Z(K,I+1) = S * Z(K,I) + C * F
|
|
Z(K,I) = C * Z(K,I) - S * F
|
|
180 CONTINUE
|
|
C
|
|
200 CONTINUE
|
|
C
|
|
D(L) = D(L) - P
|
|
E(L) = G
|
|
E(M) = 0.0E0
|
|
GO TO 105
|
|
240 CONTINUE
|
|
C .......... ORDER EIGENVALUES AND EIGENVECTORS ..........
|
|
DO 300 II = 2, N
|
|
I = II - 1
|
|
K = I
|
|
P = D(I)
|
|
C
|
|
DO 260 J = II, N
|
|
IF (D(J) .GE. P) GO TO 260
|
|
K = J
|
|
P = D(J)
|
|
260 CONTINUE
|
|
C
|
|
IF (K .EQ. I) GO TO 300
|
|
D(K) = D(I)
|
|
D(I) = P
|
|
C
|
|
DO 280 J = 1, N
|
|
P = Z(J,I)
|
|
Z(J,I) = Z(J,K)
|
|
Z(J,K) = P
|
|
280 CONTINUE
|
|
C
|
|
300 CONTINUE
|
|
C
|
|
GO TO 1001
|
|
C .......... SET ERROR -- NO CONVERGENCE TO AN
|
|
C EIGENVALUE AFTER 30 ITERATIONS ..........
|
|
1000 IERR = L
|
|
1001 RETURN
|
|
END
|