mirror of
https://git.planet-casio.com/Lephenixnoir/OpenLibm.git
synced 2025-01-01 06:23:39 +01:00
306 lines
9.8 KiB
Fortran
306 lines
9.8 KiB
Fortran
*DECK DTPMV
|
|
SUBROUTINE DTPMV (UPLO, TRANS, DIAG, N, AP, X, INCX)
|
|
C***BEGIN PROLOGUE DTPMV
|
|
C***PURPOSE Perform one of the matrix-vector operations.
|
|
C***LIBRARY SLATEC (BLAS)
|
|
C***CATEGORY D1B4
|
|
C***TYPE DOUBLE PRECISION (STPMV-S, DTPMV-D, CTPMV-C)
|
|
C***KEYWORDS LEVEL 2 BLAS, LINEAR ALGEBRA
|
|
C***AUTHOR Dongarra, J. J., (ANL)
|
|
C Du Croz, J., (NAG)
|
|
C Hammarling, S., (NAG)
|
|
C Hanson, R. J., (SNLA)
|
|
C***DESCRIPTION
|
|
C
|
|
C DTPMV performs one of the matrix-vector operations
|
|
C
|
|
C x := A*x, or x := A'*x,
|
|
C
|
|
C where x is an n element vector and A is an n by n unit, or non-unit,
|
|
C upper or lower triangular matrix, supplied in packed form.
|
|
C
|
|
C Parameters
|
|
C ==========
|
|
C
|
|
C UPLO - CHARACTER*1.
|
|
C On entry, UPLO specifies whether the matrix is an upper or
|
|
C lower triangular matrix as follows:
|
|
C
|
|
C UPLO = 'U' or 'u' A is an upper triangular matrix.
|
|
C
|
|
C UPLO = 'L' or 'l' A is a lower triangular matrix.
|
|
C
|
|
C Unchanged on exit.
|
|
C
|
|
C TRANS - CHARACTER*1.
|
|
C On entry, TRANS specifies the operation to be performed as
|
|
C follows:
|
|
C
|
|
C TRANS = 'N' or 'n' x := A*x.
|
|
C
|
|
C TRANS = 'T' or 't' x := A'*x.
|
|
C
|
|
C TRANS = 'C' or 'c' x := A'*x.
|
|
C
|
|
C Unchanged on exit.
|
|
C
|
|
C DIAG - CHARACTER*1.
|
|
C On entry, DIAG specifies whether or not A is unit
|
|
C triangular as follows:
|
|
C
|
|
C DIAG = 'U' or 'u' A is assumed to be unit triangular.
|
|
C
|
|
C DIAG = 'N' or 'n' A is not assumed to be unit
|
|
C triangular.
|
|
C
|
|
C Unchanged on exit.
|
|
C
|
|
C N - INTEGER.
|
|
C On entry, N specifies the order of the matrix A.
|
|
C N must be at least zero.
|
|
C Unchanged on exit.
|
|
C
|
|
C AP - DOUBLE PRECISION array of DIMENSION at least
|
|
C ( ( n*( n + 1))/2).
|
|
C Before entry with UPLO = 'U' or 'u', the array AP must
|
|
C contain the upper triangular matrix packed sequentially,
|
|
C column by column, so that AP( 1 ) contains a( 1, 1 ),
|
|
C AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 )
|
|
C respectively, and so on.
|
|
C Before entry with UPLO = 'L' or 'l', the array AP must
|
|
C contain the lower triangular matrix packed sequentially,
|
|
C column by column, so that AP( 1 ) contains a( 1, 1 ),
|
|
C AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 )
|
|
C respectively, and so on.
|
|
C Note that when DIAG = 'U' or 'u', the diagonal elements of
|
|
C A are not referenced, but are assumed to be unity.
|
|
C Unchanged on exit.
|
|
C
|
|
C X - DOUBLE PRECISION array of dimension at least
|
|
C ( 1 + ( n - 1 )*abs( INCX ) ).
|
|
C Before entry, the incremented array X must contain the n
|
|
C element vector x. On exit, X is overwritten with the
|
|
C transformed vector x.
|
|
C
|
|
C INCX - INTEGER.
|
|
C On entry, INCX specifies the increment for the elements of
|
|
C X. INCX must not be zero.
|
|
C Unchanged on exit.
|
|
C
|
|
C***REFERENCES Dongarra, J. J., Du Croz, J., Hammarling, S., and
|
|
C Hanson, R. J. An extended set of Fortran basic linear
|
|
C algebra subprograms. ACM TOMS, Vol. 14, No. 1,
|
|
C pp. 1-17, March 1988.
|
|
C***ROUTINES CALLED LSAME, XERBLA
|
|
C***REVISION HISTORY (YYMMDD)
|
|
C 861022 DATE WRITTEN
|
|
C 910605 Modified to meet SLATEC prologue standards. Only comment
|
|
C lines were modified. (BKS)
|
|
C***END PROLOGUE DTPMV
|
|
C .. Scalar Arguments ..
|
|
INTEGER INCX, N
|
|
CHARACTER*1 DIAG, TRANS, UPLO
|
|
C .. Array Arguments ..
|
|
DOUBLE PRECISION AP( * ), X( * )
|
|
C .. Parameters ..
|
|
DOUBLE PRECISION ZERO
|
|
PARAMETER ( ZERO = 0.0D+0 )
|
|
C .. Local Scalars ..
|
|
DOUBLE PRECISION TEMP
|
|
INTEGER I, INFO, IX, J, JX, K, KK, KX
|
|
LOGICAL NOUNIT
|
|
C .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
C .. External Subroutines ..
|
|
EXTERNAL XERBLA
|
|
C***FIRST EXECUTABLE STATEMENT DTPMV
|
|
C
|
|
C Test the input parameters.
|
|
C
|
|
INFO = 0
|
|
IF ( .NOT.LSAME( UPLO , 'U' ).AND.
|
|
$ .NOT.LSAME( UPLO , 'L' ) )THEN
|
|
INFO = 1
|
|
ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
|
|
$ .NOT.LSAME( TRANS, 'T' ).AND.
|
|
$ .NOT.LSAME( TRANS, 'C' ) )THEN
|
|
INFO = 2
|
|
ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
|
|
$ .NOT.LSAME( DIAG , 'N' ) )THEN
|
|
INFO = 3
|
|
ELSE IF( N.LT.0 )THEN
|
|
INFO = 4
|
|
ELSE IF( INCX.EQ.0 )THEN
|
|
INFO = 7
|
|
END IF
|
|
IF( INFO.NE.0 )THEN
|
|
CALL XERBLA( 'DTPMV ', INFO )
|
|
RETURN
|
|
END IF
|
|
C
|
|
C Quick return if possible.
|
|
C
|
|
IF( N.EQ.0 )
|
|
$ RETURN
|
|
C
|
|
NOUNIT = LSAME( DIAG, 'N' )
|
|
C
|
|
C Set up the start point in X if the increment is not unity. This
|
|
C will be ( N - 1 )*INCX too small for descending loops.
|
|
C
|
|
IF( INCX.LE.0 )THEN
|
|
KX = 1 - ( N - 1 )*INCX
|
|
ELSE IF( INCX.NE.1 )THEN
|
|
KX = 1
|
|
END IF
|
|
C
|
|
C Start the operations. In this version the elements of AP are
|
|
C accessed sequentially with one pass through AP.
|
|
C
|
|
IF( LSAME( TRANS, 'N' ) )THEN
|
|
C
|
|
C Form x:= A*x.
|
|
C
|
|
IF( LSAME( UPLO, 'U' ) )THEN
|
|
KK =1
|
|
IF( INCX.EQ.1 )THEN
|
|
DO 20, J = 1, N
|
|
IF( X( J ).NE.ZERO )THEN
|
|
TEMP = X( J )
|
|
K = KK
|
|
DO 10, I = 1, J - 1
|
|
X( I ) = X( I ) + TEMP*AP( K )
|
|
K = K + 1
|
|
10 CONTINUE
|
|
IF( NOUNIT )
|
|
$ X( J ) = X( J )*AP( KK + J - 1 )
|
|
END IF
|
|
KK = KK + J
|
|
20 CONTINUE
|
|
ELSE
|
|
JX = KX
|
|
DO 40, J = 1, N
|
|
IF( X( JX ).NE.ZERO )THEN
|
|
TEMP = X( JX )
|
|
IX = KX
|
|
DO 30, K = KK, KK + J - 2
|
|
X( IX ) = X( IX ) + TEMP*AP( K )
|
|
IX = IX + INCX
|
|
30 CONTINUE
|
|
IF( NOUNIT )
|
|
$ X( JX ) = X( JX )*AP( KK + J - 1 )
|
|
END IF
|
|
JX = JX + INCX
|
|
KK = KK + J
|
|
40 CONTINUE
|
|
END IF
|
|
ELSE
|
|
KK = ( N*( N + 1 ) )/2
|
|
IF( INCX.EQ.1 )THEN
|
|
DO 60, J = N, 1, -1
|
|
IF( X( J ).NE.ZERO )THEN
|
|
TEMP = X( J )
|
|
K = KK
|
|
DO 50, I = N, J + 1, -1
|
|
X( I ) = X( I ) + TEMP*AP( K )
|
|
K = K - 1
|
|
50 CONTINUE
|
|
IF( NOUNIT )
|
|
$ X( J ) = X( J )*AP( KK - N + J )
|
|
END IF
|
|
KK = KK - ( N - J + 1 )
|
|
60 CONTINUE
|
|
ELSE
|
|
KX = KX + ( N - 1 )*INCX
|
|
JX = KX
|
|
DO 80, J = N, 1, -1
|
|
IF( X( JX ).NE.ZERO )THEN
|
|
TEMP = X( JX )
|
|
IX = KX
|
|
DO 70, K = KK, KK - ( N - ( J + 1 ) ), -1
|
|
X( IX ) = X( IX ) + TEMP*AP( K )
|
|
IX = IX - INCX
|
|
70 CONTINUE
|
|
IF( NOUNIT )
|
|
$ X( JX ) = X( JX )*AP( KK - N + J )
|
|
END IF
|
|
JX = JX - INCX
|
|
KK = KK - ( N - J + 1 )
|
|
80 CONTINUE
|
|
END IF
|
|
END IF
|
|
ELSE
|
|
C
|
|
C Form x := A'*x.
|
|
C
|
|
IF( LSAME( UPLO, 'U' ) )THEN
|
|
KK = ( N*( N + 1 ) )/2
|
|
IF( INCX.EQ.1 )THEN
|
|
DO 100, J = N, 1, -1
|
|
TEMP = X( J )
|
|
IF( NOUNIT )
|
|
$ TEMP = TEMP*AP( KK )
|
|
K = KK - 1
|
|
DO 90, I = J - 1, 1, -1
|
|
TEMP = TEMP + AP( K )*X( I )
|
|
K = K - 1
|
|
90 CONTINUE
|
|
X( J ) = TEMP
|
|
KK = KK - J
|
|
100 CONTINUE
|
|
ELSE
|
|
JX = KX + ( N - 1 )*INCX
|
|
DO 120, J = N, 1, -1
|
|
TEMP = X( JX )
|
|
IX = JX
|
|
IF( NOUNIT )
|
|
$ TEMP = TEMP*AP( KK )
|
|
DO 110, K = KK - 1, KK - J + 1, -1
|
|
IX = IX - INCX
|
|
TEMP = TEMP + AP( K )*X( IX )
|
|
110 CONTINUE
|
|
X( JX ) = TEMP
|
|
JX = JX - INCX
|
|
KK = KK - J
|
|
120 CONTINUE
|
|
END IF
|
|
ELSE
|
|
KK = 1
|
|
IF( INCX.EQ.1 )THEN
|
|
DO 140, J = 1, N
|
|
TEMP = X( J )
|
|
IF( NOUNIT )
|
|
$ TEMP = TEMP*AP( KK )
|
|
K = KK + 1
|
|
DO 130, I = J + 1, N
|
|
TEMP = TEMP + AP( K )*X( I )
|
|
K = K + 1
|
|
130 CONTINUE
|
|
X( J ) = TEMP
|
|
KK = KK + ( N - J + 1 )
|
|
140 CONTINUE
|
|
ELSE
|
|
JX = KX
|
|
DO 160, J = 1, N
|
|
TEMP = X( JX )
|
|
IX = JX
|
|
IF( NOUNIT )
|
|
$ TEMP = TEMP*AP( KK )
|
|
DO 150, K = KK + 1, KK + N - J
|
|
IX = IX + INCX
|
|
TEMP = TEMP + AP( K )*X( IX )
|
|
150 CONTINUE
|
|
X( JX ) = TEMP
|
|
JX = JX + INCX
|
|
KK = KK + ( N - J + 1 )
|
|
160 CONTINUE
|
|
END IF
|
|
END IF
|
|
END IF
|
|
C
|
|
RETURN
|
|
C
|
|
C End of DTPMV .
|
|
C
|
|
END
|