mirror of
https://git.planet-casio.com/Lephenixnoir/OpenLibm.git
synced 2025-01-01 06:23:39 +01:00
79 lines
2.4 KiB
Fortran
79 lines
2.4 KiB
Fortran
*DECK SASUM
|
|
REAL FUNCTION SASUM (N, SX, INCX)
|
|
C***BEGIN PROLOGUE SASUM
|
|
C***PURPOSE Compute the sum of the magnitudes of the elements of a
|
|
C vector.
|
|
C***LIBRARY SLATEC (BLAS)
|
|
C***CATEGORY D1A3A
|
|
C***TYPE SINGLE PRECISION (SASUM-S, DASUM-D, SCASUM-C)
|
|
C***KEYWORDS BLAS, LINEAR ALGEBRA, SUM OF MAGNITUDES OF A VECTOR
|
|
C***AUTHOR Lawson, C. L., (JPL)
|
|
C Hanson, R. J., (SNLA)
|
|
C Kincaid, D. R., (U. of Texas)
|
|
C Krogh, F. T., (JPL)
|
|
C***DESCRIPTION
|
|
C
|
|
C B L A S Subprogram
|
|
C Description of Parameters
|
|
C
|
|
C --Input--
|
|
C N number of elements in input vector(S)
|
|
C SX single precision vector with N elements
|
|
C INCX storage spacing between elements of SX
|
|
C
|
|
C --Output--
|
|
C SASUM single precision result (zero if N .LE. 0)
|
|
C
|
|
C Returns sum of magnitudes of single precision SX.
|
|
C SASUM = sum from 0 to N-1 of ABS(SX(IX+I*INCX)),
|
|
C where IX = 1 if INCX .GE. 0, else IX = 1+(1-N)*INCX.
|
|
C
|
|
C***REFERENCES C. L. Lawson, R. J. Hanson, D. R. Kincaid and F. T.
|
|
C Krogh, Basic linear algebra subprograms for Fortran
|
|
C usage, Algorithm No. 539, Transactions on Mathematical
|
|
C Software 5, 3 (September 1979), pp. 308-323.
|
|
C***ROUTINES CALLED (NONE)
|
|
C***REVISION HISTORY (YYMMDD)
|
|
C 791001 DATE WRITTEN
|
|
C 890831 Modified array declarations. (WRB)
|
|
C 890831 REVISION DATE from Version 3.2
|
|
C 891214 Prologue converted to Version 4.0 format. (BAB)
|
|
C 900821 Modified to correct problem with a negative increment.
|
|
C (WRB)
|
|
C 920501 Reformatted the REFERENCES section. (WRB)
|
|
C***END PROLOGUE SASUM
|
|
REAL SX(*)
|
|
INTEGER I, INCX, IX, M, MP1, N
|
|
C***FIRST EXECUTABLE STATEMENT SASUM
|
|
SASUM = 0.0E0
|
|
IF (N .LE. 0) RETURN
|
|
C
|
|
IF (INCX .EQ. 1) GOTO 20
|
|
C
|
|
C Code for increment not equal to 1.
|
|
C
|
|
IX = 1
|
|
IF (INCX .LT. 0) IX = (-N+1)*INCX + 1
|
|
DO 10 I = 1,N
|
|
SASUM = SASUM + ABS(SX(IX))
|
|
IX = IX + INCX
|
|
10 CONTINUE
|
|
RETURN
|
|
C
|
|
C Code for increment equal to 1.
|
|
C
|
|
C Clean-up loop so remaining vector length is a multiple of 6.
|
|
C
|
|
20 M = MOD(N,6)
|
|
IF (M .EQ. 0) GOTO 40
|
|
DO 30 I = 1,M
|
|
SASUM = SASUM + ABS(SX(I))
|
|
30 CONTINUE
|
|
IF (N .LT. 6) RETURN
|
|
40 MP1 = M + 1
|
|
DO 50 I = MP1,N,6
|
|
SASUM = SASUM + ABS(SX(I)) + ABS(SX(I+1)) + ABS(SX(I+2)) +
|
|
1 ABS(SX(I+3)) + ABS(SX(I+4)) + ABS(SX(I+5))
|
|
50 CONTINUE
|
|
RETURN
|
|
END
|