mirror of
https://github.com/ashinn/chibi-scheme.git
synced 2025-05-19 13:49:17 +02:00
8b5eb68238
They can be close()d explicitly with close-file-descriptor, and will close() on gc, but only explicitly closing the last port on them will close the fileno. Notably needed for network sockets where we open separate input and output ports on the same socket.
23 lines
703 B
Scheme
23 lines
703 B
Scheme
|
|
(define-library (srfi 2)
|
|
(export and-let*)
|
|
(import (chibi))
|
|
(begin
|
|
(define-syntax and-let*
|
|
(syntax-rules ()
|
|
((and-let* () . body)
|
|
(begin #t . body))
|
|
((and-let* ((var expr)))
|
|
expr)
|
|
((and-let* ((expr)))
|
|
expr)
|
|
((and-let* (expr)) ; Extension: in SRFI-2 this can only be a var ref
|
|
expr)
|
|
((and-let* ((var expr) . rest) . body)
|
|
(let ((var expr))
|
|
(and var (and-let* rest . body))))
|
|
((and-let* ((expr) . rest) . body)
|
|
(and expr (and-let* rest . body)))
|
|
((and-let* (expr . rest) . body) ; Same extension as above
|
|
(let ((tmp expr))
|
|
(and tmp (and-let* rest . body))))))))
|